テーブル参照と補間処理

WORK00          DSEG    SADDRP
CONVDATA:
        DS      2               ;入力パラメータと結果の戻り領域
WORK01          DSEG    SADDR
WORK1:  DS      1

CONVSUB:
        PUSH    AX
        PUSH    HL
        MOVW    AX,CONVDATA     ;Aに上位、Xに下位
        MOVW    HL,#CONVDATA
        ROR4    [HL]            ;Aの下位4ビットと[HL]を1/16する
        MOV     A,[HL]
        AND     A,#00111110b    ;オフセット値を得る
        ADD     A,#LOW TABLE    ;下位アドレスを計算
        MOV     L,A
        MOV     A,#0
        ADDC    A,#HIGH TABLE   ;上位アドレスを計算
        MOV     H,A             ;HLはテーブルの対象を指す
        MOV     A,[HL]          ;下位バイトを読み出す
        MOV     CONVDATA,A      ;下位バイトの初期値としてセット
        MOV     A,[HL+1]
        MOV     CONVDATA+1,A    ;上位バイトのセット

        MOV     A,X
        AND     A,#00011111b    ;補間のためのデータを得る
        BZ      $EXITS          ;補間不要なら終了
;
;       補間(加重平均)のための準備
;       (スタックに計算データを入れておく)
;
        MOV     WORK1,#0        ;上位データを初期化
        MOV     X,A             ;補間データをXレジスタにセット
        MOV     A,[HL+3]        ;次のデータの上位をセット
        PUSH    AX              ;計算データをセーブ
        MOV     A,[HL+2]        ;次のデータの下位をセット
        PUSH    AX              ;計算データをセーブ
        MOV     A,#31
        SUB     A,X             ;32に対する残り数を計算
        MOV     X,A
        MOV     A,[HL+1]        ;テーブルの上位データをセット
        PUSH    AX              ;計算データをセーブ
        MOV     A,[HL]          ;テーブルから下位データを
        MOVW    HL,#CONVDATA    ;ポインターを設定
;
;       テーブルの検索データ分の積算を行なう
;
        CALL    !SEKIWA         ;下位データ演算
        POP     AX
        INCW    HL
        CALL    !SEKIWA         ;上位の計算と結果の積算
;
;       補間データから次のデータ重み分の積算を行なう
;
        POP     AX
        DECW    HL
        CALL    !SEKIWA
        POP     AX
        INCW    HL
        CALL    !SEKIWA

        MOV     A,CONVDATA      ;結果の下位をロード
        ADD     A,#00010000b    ;四捨五入のために0.5分を加算
        BNC     $NEXT
        INC     CONVDATA+1      ;上位に桁上げ
NEXT:   AND     A,#11100000b    ;未使用ビットをマスク
        ROR     A,1             ;結果を下位4ビットに
        ROR     A,1             ;A=00XXX000、CY=0
        ROR     A,1             ;A=000XXX00、CY=0
        ROR     A,1             ;A=0000XXX0、CY=0
        ROL4    [HL]            ;結果を1/16する
        RORC    A,1             ;さらに1/2する
        XCH     A,[HL]          ;上位3ビットと下位を交換
        RORC    A,1             ;下位も1/2する
        MOV     CONVDATA,A      ;結果を保存

EXITS:  POP     HL
        POP     AX
        RET

;       8ビットの積和演算
;  (結果は16ビットに収まるものとする)
;
SEKIWA:
        MULU    X               ;重みの計算
        XCH     A,X             ;結果の上位と下位を交換
        ADD     A,[HL]          ;下位を積算
        MOV     [HL],A          ;結果をセーブ
        MOV     A,X             ;結果の上位をもってくる
        ADDC    A,[HL+1]        ;上位への桁上げ計算
        MOV     [HL+1],A        ;上位バイトをセーブ
        RET

TAREA   CSEG    AT      200H
;
;       sin0〜sin(/2)を32分割したときの値を1023倍した値のテーブル

TABLE:  DW      0,      50,     100,    150
        DW      200,    249,    297,    345
        DW      392,    437,    482,    526
        DW      568,    609,    649,    687
        DW      723,    758,    791,    822
        DW      851,    877,    902,    925
        DW      945,    963,    949,    992
        DW      1003,   1012,   1018,   1022
        DW      1023

2048(=)以上への対応 以上への対応はテーブルやオフセットのマスクだけでは対応できません。これは結果の値の範囲(負の値をどのように表現するか)を見直す必要があるからです。 このプログラムでは結果の値の範囲として0〜1023を扱えるようになっています。従って、sin/2〜sin3/2を0〜1023で表す必要があります。具体的には、1(sin/2)を1023、0(sin)を512、-1(sin3/2)を1で表現することで対応できるようになります。 負の数を2の補数で表現する場合には、このプログラムでは対応できませんので、このプログラムの外で符号を付ける(0から引く)ような処理を追加する必要があります。

(2006/02)