78K0S用ソフトウェアI2Cバス通信プログラム

• PMレジスタに0をセット → 出力ポート → ロウ・レベル
• PMレジスタに1をセット → 入力ポート → ハイ・レベル

• バスが使用されていない状態(1)や(10)では、2つの信号線SCLとSDAはハイ・レベル状態です。
• 基本的にSDAはSCLがLのときに変化して、SCLがHの状態ではSDAは安定しています。
• スタート･コンディションの発行(SCLがHの状態でSDAを立ち下げる)後にはSCLがHでSDAがLの状態となります。この後で、スレーブのアドレスを送信するには、まずSCLを立ち下げます。
• アドレスの送信やデータ通信でSCLが9クロック送られた後の(5)や(6)ではSCLがLの状態で次の通信の準備を行ないます。次の通信がない場合には、SDAはHとなっています。そうでない場合(7)や(8)には次のデータの先頭ビットが出力されます。
• 8ビット・データの送受信後(9)にSCLはLとなりACK応答待ちの状態となります。
• (6)や(9)で、スレーブはSCLをロウ・レベルに引くことで通信を待たせることができます。従って、マスタはSCLがハイ・レベルになったことを確認してから次の処理に移る必要があります。

comdata DSEG     SADDR      ; saddr領域に変数を確保します。
i2c_error:  DS  1           ; エラー・フラグ
    BSEG                    ; ビット変数領域であることを示します。
acke    DBIT                ; ACK制御フラグ

PMSW_SDA    equ PM2.2       ; SDA信号制御で使用
PSW_SDA     equ P2.2        ; SDA信号の読出しで使用
PSW_I2C     EQU P2          ; 使用するのはポート2

PMSW_SCL    equ PM2.3       ; SCL信号制御で使用
PSW_SCL     equ P2.3        ; SCL信号の読出しで使用

_scl_hi         macro       ; _scl_hiと言うマクロの定義を示す
        set1    PMSW_SCL    ; PM2.3をセットして入力にする
        endm                ; マクロ定義の終了を示す


_scl_lo         macro
        clr1    PMSW_SCL    ; PM2.3をクリアしてSCLにロウ出力
        endm


_sda_hi         macro
        set1    PMSW_SDA    ; PM2.2をセットして入力にする
        endm

_sda_lo         macro
        clr1    PMSW_SDA    ; PM2.2をクリアしてSDAにロウ出力

    public  __setup_i2c_port    ; 外部から使えるようにpublic宣言します
__setup_i2c_port:
    MOV PSW_I2C,#0              ; 端子をオープン・ドレインと等価に
                                ; 使用するのでデータは0に固定
    _scl_hi                     ; PMを入力にする
    _sda_hi
    RET

;bit    _i2c_busy(void)
    public  __i2c_busy
__i2c_busy:
i2c_busy:
    SET1    CY                  ; ビジーフラグをセットしておく
    BF  PSW_SDA,$busbusy        ; SDAラインのチェック
    BF  PSW_SCL,$busbusy        ; SCLラインのチェック
    CLR1    CY                  ; 開放されていればフラグリセット
busbusy:
    RET

;bit    _free_i2c_bus(void)
    public  __free_i2c_bus
__free_i2c_bus:
free_i2c_bus:
    _sda_hi                 ; 念のためにSDAを立ち上げる
    _scl_hi                 ; 念のためにSCLを立ち上げる
    CALL    !i2c_busy       ; バスの状態確認
    NOT1    CY
    BC  $free_exit1         ; バスが開放されていれば抜ける
    MOV A,#0                ; 限度を256回に設定
dumyclkloop:
    CALL    !scl_pulse      ; SCLにダミークロックを出力
    CALL    !i2c_busy       ; バスの状態確認
    NOT1    CY
    BC  $free_exit1         ; バスが開放されていれば抜ける
    DEC A                   ; 限度を超えていないか?
    BNZ $dumyclkloop        ; 限度以内なら継続
    RET                     ; エラーならキャリーをセットして戻る
free_exit1:
    PUSH    PSW             ; 念のためにフラグをセーブ
    CALL    !I2C_STPR       ; ストップ･コンディション発行
    POP PSW
    RET

scl_pulse:
    _scl_lo                 ; 6:SCLを立ち下げる
    NOP                     ; 2:ロウ・レベル幅1.3μ秒を
    NOP                     ; 2:確保するために、11クロック
    NOP                     ; 2:以上時間を確保して立ち上げる
    _scl_hi                 ; 6:SCLを立ち上げる
    RET                     ; 6:これだけでハイ・レベルは十分

    public  __I2C_STR
__I2C_STR:
I2C_STR:
    _sda_hi                 ; 6:準備のためSDAをハイに設定する
    NOP                     ; 2:
    _scl_hi                 ; 6:SCLをハイに設定する
    BF  PSW_SCL,$$          ;10:SCLの立ち上がり検出
    _sda_lo                 ; 6:スタート・コンディション発行
    RET                     ; 6:

    public  __I2C_STPR
__I2C_STPR:
I2C_STPR:
    _sda_lo                 ; 6:SDAを立ち下げる。これでスタート
    NOP                     ; 2:コンディションと解釈されても、
    NOP                     ; 2:直ぐにストップ・コンディションを
                            ;   発行するので構わない。
    _scl_hi                 ; 6:念のためにSCLをハイに設定する
    BF  PSW_SCL,$$          ;10:SCLの立ち上がり検出
    _sda_hi                 ; 6:ストップ・コンディション発行
    NOP                     ; 2:
    NOP                     ; 2:
    RET                     ; 6:

;bit    _put_i2c(u8 data);
    public  __put_i2c
__put_i2c:
put_i2c:
    PUSH    BC              ; ループカウンタで使用のためセーブ
    MOV B,#8
    MOV A,X                 ; 入力データ(引数)は8ビット
;
;
OUTLOOP:
    _scl_lo                 ; 6:SCLを立ち下げてデータ出力準備
    NOP                     ; 2:立下りの時間調整用
    ROL A,1                 ; 2:MSBよりCYにシフトアウトする
    BNC $OUTLO              ; 6:データが0なら分岐
    _sda_hi                 ; 6:1を出力
    BR  $CLKHI              ; 6:SCLの立ち上げへ
OUTLO:  _sda_lo             ; 6:0を出力
    NOP                     ; 2:セットアップ時間確保
CLKHI:
      _scl_hi               ; 6:
    BF  PSW_SCL,$$          ;10:SCLの立ち上がり検出(念のため)
    DBNZ    B,$OUTLOOP      ; 6:

    POP BC                  ; 6:
    _scl_lo                 ; 6:8クロック目のSCLを立ち下げる
    NOP                     ; 2:
    _sda_hi                 ; 6:SDA を入力に切替え
    NOP                     ; 2:
    NOP                     ; 2:
    NOP                     ; 2:
    _scl_hi                 ; 6:9クロック目のSCLを立ち上げ
;
;   ウェイト解除を待つ
;
    SET1    CY              ; 2:

    BF  PSW_SCL,$$          ; SCLの立ち上がり検出待ち

    BF  PSW_SDA,$ACKOK      ;10:/ACK信号を取得
    NOT1    CY              ; 2:
ACKOK:

    _scl_lo                 ; 6:SCLを立ち下げ(9クロック目)
    NOP
    RET

;static bit  _put_i2c2(u8 data)
    public  __put_i2c2
__put_i2c2:
    CALL    !put_i2c            ; 1バイト出力
    BNC $PUTERROR               ; エラーなら終了処理へ
    RET                         ; 正常なら終了
PUTERROR:
    CALL    !I2C_STPR           ; ストップ・コンディション発行
    CLR1    CY                  ; falseにする(念のため)
    RET

;u8 _get_i2c(void);
    public  __get_i2c
__get_i2c:
    MOV A,#11111110b        ; シフトしてCY=0で終了
INLOOP:
    NOP                     ; 2:
    SET1    CY              ; 2:初期値として1をセット
    _scl_hi                 ; 6:SCLの立ち上げ
    BF  PSW_SCL,$$          ; SCLの立ち上がり検出

    BT  PSW_SDA,$DATAIS1    ;10:
    NOT1    CY              ; 2:データが0ならキャリーを反転
DATAIS1:
    ROLC    A,1             ; 2:読み込んだ結果をAレジスタにシフトイン
    _scl_lo                 ; 6:SCLの立ち下げ
    BC  $INLOOP             ; 6:8ビット分ループ

;******************************************************
;*  ACK応答の制御                                  *
;******************************************************
    BF  _acke,$ACKEND           ;10:ACK応答するかをチェック
    _sda_lo                     ; 6:ACKを戻す
ACKEND:
    _scl_hi                     ; 6:9クロック目の立ち上げ
;
;     ここではスレーブが8クロック・ウェイトしていたときの対応で
;   SCL信号の立ち上がりを待っている。通常は不要か。
;
    BF  PSW_SCL,$$              ; SCLの立ち上がり検出(念のため)
    NOP                         ; 2:
    _scl_lo                     ; 6:9クロック目の立ち下げ

    MOV C,A                     ; 4:return (u8)
    _sda_hi                     ; 6:終わったらSDAは入力にしておく
    RET

;static u8 _clear_i2c_error(void)
    public  __clear_i2c_error
__clear_i2c_error:
clear_i2c_error:
    MOV i2c_error,#I2C_NO_ERROR ;
    MOV C,#I2C_NO_ERROR
    RET

I2C_NO_ERROR        = 0x00:エラー無し
I2C_BUS_NOT_FREE    = 0x10:バスが開放されていなかった
I2C_ADDR_NACK       = 0x11:スレーブがアドレスに反応しなかった
I2C_RADDR_NACK      = 0x12:スレーブがREADアドレスに反応しなかった
I2C_REG_ADDR_NACK   = 0x13:スレーブから予期せぬ NACK が帰って来た(レジスタ)
I2C_DATA_NACK       = 0x14:スレーブから予期せぬ NACK が帰って来た(データ)

;static u8 _set_i2c_error(u8 error)
    public  __set_i2c_error
__set_i2c_error:
set_i2c_error:
    XCH A,X                     ; エラー・データを取り込む
    MOV i2c_error,A             ; エラー・フラグにセット
    MOV C,A                     ; 戻り値をセット
    XCH A,X
    RET

;static u8 _get_i2c_error(void)
    public  __get_i2c_error
__get_i2c_error:
get_i2c_error:
    PUSH    AX
    MOV A,i2c_error             ; エラー・フラグの読み出し
    MOV C,A                     ; 戻り値にセット
    POP AX
    RET

;void _ACK_EN(void)
    public  __ACK_EN
__ACK_EN:
ACK_EN:
    SET1    acke                ; ACK応答フラグセット
    RET

;void _ACK_DS(void)
    public  __ACK_DS
__ACK_DS:
ACK_DS:
    CLR1    acke                ; ACK応答フラグクリア
    RET

;**************************************************************
;*                                                            *
;*  I2C デバイスにブロックデータ送信                          *
;*  対象は256バイト以下のサブアドレスもつデバイス          *
;*                  ADR(W), SUB_ADR, DATA...                  *
;**************************************************************
;*  [i] : u8 i2c_adr    ... I2C スレーブのアドレス            *
;*  [i] : u8 reg_adr    ... スレーブ内部のアドレス            *
;*  [i] : u8 *data      ... 書き込みデータのアドレス          *
;*  [i] : u8 size       ... バイト数(0x00 = 256)              *
;*  [r] : u8            ... error code                        *
;*                                                            *
;*    実際の引数はスタックに16ビット単位で積まれて          *
;*  渡されるので、SPの値をHLに持ってきて、HL相対に      *
;*  より必要な引数を得る。                                    *
;*                                                            *
;**************************************************************
;u8 _write_i2c_block(u8 i2c_adr, u8 reg_adr, u8 *data, u8 size)

    public  __write_i2c_block
__write_i2c_block:
    PUSH    HL                  ; レジスタをセーブ
    PUSH    AX
;
;  このサブルーチンはC(ノーマル・モード)から関数コールされる。
;  そのため、この段階でのスタックのデータは以下のようになっている
;
;   sp   : Xレジスタ(第1引数) :スレーブ・アドレス
;   sp+1 : Aレジスタ            :未使用(レジスタのセーブのみ)
;   sp+2 : Lレジスタ            :未使用(レジスタのセーブのみ)
;   sp+3 : Hレジスタ            :未使用(レジスタのセーブのみ)
;   sp+4 : PCの下位           :戻りアドレス下位
;   sp+5 : PCの上位           :戻りアドレス上位
;   sp+6 : 第2引数             :スレーブ内アドレス
;   sp+7 :                      :未使用
;   sp+8 : 第3引数の下位       :書き込みデータの格納アドレス
;   sp+9 : 第3引数の上位
;   sp+10: 第4引数             :書き込みデータ数

    MOVW    AX,SP               ; 2つ目以降の引数を取り出す準備
    MOVW    HL,AX
    MOV X,#I2C_BUS_NOT_FREE
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    CALL    !free_i2c_bus       ; バスが開放できるか
    BNC $EXITSUB                ; 開放できなければ戻る

    CALL    !I2C_STR            ; スタート･コンディション発行

    MOV X,#I2C_ADDR_NACK
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    MOV A,[HL]                  ; スレーブ・アドレスを取り出す
    AND A,#11111110b            ; 方向フラグを送信に
    MOV X,A
    CALL    !put_i2c2           ; 送信方向でスレーブアドレスを送信
    BNC $EXITSUB                ; スレーブから応答なければエラーで戻る

    MOV X,#I2C_REG_ADDR_NACK    ;
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    MOV A,[HL+6]                ; スタックから第2引数を取り出す
    MOV X,A
    CALL    !put_i2c2           ; スレーブ内アドレスを送信
    BNC $EXITSUB                ; スレーブから応答なければエラーで戻る

    MOV A,[HL+10]               ; スタックから第4引数を取り出す
    MOV B,A                     ; データ数をBレジスタに設定
    MOV A,[HL +8]               ; スタックから第3引数を取り出す。
    MOV X,A                     ; 第3引数(書き込みデータ格納アドレス)
    MOV A,[HL+9]                ; を
    MOVW    HL,AX               ; HLレジスタに設定する
    MOV X,#I2C_DATA_NACK        ; ダミーでエラー・フラグにデータへの
    CALL    !set_i2c_error      ; ACK応答無しを設定
WBLOOP:
    MOV A,[HL]                  ; 書き込みデータをバッファから読み出す
    MOV X,A
    CALL    !put_i2c2           ; データを書き込む
    BNC $EXITSUB                ; エラーが発生したら戻る

    INCW    HL                  ; データアドレスを更新
    DBNZ    B,$WBLOOP           ; データ数分繰り返す

    CALL    !I2C_STPR           ; バスを開放
    CALL    !clear_i2c_error    ; エラー・フラグをクリア
EXITSUB:
    MOV B,#0                    ; 戻り値の上位をクリア(不要?)
    POP AX
    POP HL
    RET

;****************************************************************
;*                                                              *
;*  I2C デバイスからブロックデータを受信                        *
;*  対象は256バイト以下のサブ・アドレスをもつデバイス        *
;*                  ADR(W), SUB_ADR, DATA...                    *
;****************************************************************
;*  [i] : u8 i2c_adr    ... I2C スレーブのアドレス              *
;*  [i] : u8 reg_adr    ... スレーブ内部のアドレス              *
;*  [i] : u8 *data      ... 書き込みデータのアドレス            *
;*  [i] : u8 size       ... バイト数(0x00 = 256)                *
;*  [r] : u8            ... error code                          *
;*                                                              *
;*    実際の引数はスタックに16ビット単位で積まれて            *
;*  渡されるので、SPの値をHLに持ってきて、HL相対に        *
;*  より必要な引数を得る。HLからのアクセス時の相対            *
;*  アドレスは書き込みの方を参照のこと。                        *
;****************************************************************
;u8 _read_i2c_block(u8 i2c_adr, u8 reg_adr, u8 *data, u8 size)

    public  __read_i2c_block
__read_i2c_block:
    PUSH    HL
    PUSH    AX
    MOVW    AX,SP               ; 2つ目以降の引数を取り出す準備
    MOVW    HL,AX               ; ポインタをHLレジスタに設定
    MOV X,#I2C_BUS_NOT_FREE
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    CALL    !free_i2c_bus       ; バスが開放できるか
    BNC $EXITSUBR               ; 開放できなければ戻る
    CALL    !I2C_STR            ; スタート･コンディション発行

    MOV X,#I2C_ADDR_NACK
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    MOV A,[HL]                  ; スレーブ・アドレスを取り出す
    AND A,#11111110b            ; 方向フラグを送信に
    MOV X,A
    CALL    !put_i2c2           ; 送信方向でスレーブアドレスを送信
    BNC $EXITSUBR               ; スレーブから応答なければエラーで戻る

    MOV X,#I2C_REG_ADDR_NACK
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    MOV A,[HL+6]                ; スタックから第2引数を取り出す
    MOV X,A
    CALL    !put_i2c2           ; スレーブ内アドレスを送信
    BNC $EXITSUBR               ; スレーブから応答なければエラーで戻る

    CALL    !I2C_STR            ; リスタート･コンディション発行

    MOV X,#I2C_RADDR_NACK
    CALL    !set_i2c_error      ; ダミーでエラーをセットしておく
    MOV A,[HL]                  ; スレーブ・アドレスを取り出す
    OR  A,#00000001b            ; 方向フラグを受信に
    MOV X,A
    CALL    !put_i2c2           ; 受信方向でスレーブアドレスを送信
    BNC $EXITSUBR               ; スレーブから応答なければエラーで戻る

    SET1    acke                ; ACK応答を設定
    MOV A,[HL+10]               ; データ数を
    MOV B,A
    MOV A,[HL+8]                ; スタックから第3引数を取り出す。
    MOV X,A                     ; 第3引数(書き込みデータ格納アドレス)
    MOV A,[HL+9]                ; を
    MOVW    HL,AX               ; HLレジスタに設定する

BRLOOP:
    MOV A,#1                    ; 最後のデータかをチェックする
    CMP A,B
    BNZ $BRNEXT                 ; 最後のデータ(残り1バイト)なら
    CLR1    acke                ; NACK応答を設定
BRNEXT:
    CALL    !get_i2c            ; データをリード
    MOV A,C                     ;
    MOV [hl],a                  ; 読み込んだデータをバッファに書き込む

    INCW    HL                  ; ポインタ更新
    DBNZ    B,$BRLOOP           ; データ数分繰り返す

    CALL    !I2C_STPR           ; バスを開放
    CALL    !clear_i2c_error    ; エラー・フラグをクリア
EXITSUBR:  
    MOV B,#00H                  ; 余分?
    POP AX
    POP HL
    RET

#pragma SFR
#pragma  EI
#pragma  DI
#pragma  NOP
typedef unsigned char   u8, uint8,  /* same as "byte"   */
            *u8Ptr, *uint8Ptr;  /* same as "bytePtr"    */
/*  エラー・フラグ操作関係処理関数  */

extern      u8  _set_i2c_error(u8 error);
extern      u8  _get_i2c_error(void);
extern      u8  _clear_i2c_error(void);

/*  エラー・フラグ状態定義          */
enum{
    I2C_NO_ERROR        = 0x00, // エラー無し(0)
    I2C_BUS_NOT_FREE    = 0x10, // バスが開放されていなかった
    I2C_ADDR_NACK       = 0x11, // スレーブがアドレスに反応なし
    I2C_RADDR_NACK      = 0x12, // スレーブがREADアドレスに反応なし
    I2C_REG_ADDR_NACK   = 0x13, // 予期せぬ NACK が帰って来た(レジスタ)
    I2C_DATA_NACK       = 0x14  // 予期せぬ NACK が帰って来た(データ)
};

/*  ACK応答制御関係処理関数      */

extern      void    _ACK_EN(void);
extern      void    _ACK_DS(void);

extern      void    _setup_i2c_port(void);
extern      bit _i2c_busy(void);
extern      bit _free_i2c_bus(void);

/*  I2Cバス初期化関係処理関数    */

extern      void    _I2C_STR(void);
extern      void    _I2C_STPR(void);

/*  I2Cバスバイト転送基本関数    */

extern      bit _put_i2c(u8 data);
extern      bit _put_i2c2(u8 data);
extern      u8  _get_i2c(void);

/*  I2Cバスブロック転送処理関数  */

extern      u8 _write_i2c_block(u8 i2c_adr, u8 reg_adr, u8 *data, u8 size);
extern      u8 _read_i2c_block(u8 i2c_adr, u8 reg_adr, u8 *data, u8 size);

    LVIS = 0x00;        /* select VLI=4V */
    LVIM = 0b10000000;  /* Start VLI detection*/
    PCC = 0x00;         /* CPU clock is fx/4 */
    _clear_i2c_error(); /* I2C flag clear */
    _setup_i2c_port();  /* Initialize I2C port*/
/*
    wait for 0.17ms(=0.2ms-(32+30)*52/1000)
*/
    for (work1 = 0; work1 < 10; work1++){
        NOP();
    }
    WDTM = 0b01110000;  /* Stop WDT */
    LSRSTOP = 1;        /* Stop Low Speed OSC */
    while ( LVIF ){
        NOP();
    }   /* wait VDD > 4V */

    PPCC = 0;       /* CPU clock is fx=fR */
    IF0 = 0x00;     /* Clear interrupt */

    @@OPTB  CSEG    AT  0080H
    DB  10011100b
    DB  11111111b
    END

• 最初にI2Cバスが開放状態であることを確認/バスを開放します。
• 開放できなければ、エラーで戻ります。
• スタート･コンディションを発行してバスの使用を開始します。
• EEPROMのアドレスを指定して送信方向でアドレスを送信します。
• 次にEEPROM内部の書き込みたいアドレスを送信します。
• 以降は指定されたバイト数のデータを送信します。
• 送信が完了してストップ･コンディションを発行します。(EEPROMはストップ･コンディションを検出して、送信されたデータを内部のセルに書き込みます。)

u8 write_i2c_block(u8 i2c_adr, u8 reg_adr, u8 *data, u8 size)
{
    i2c_adr &= 0xfe;
    if (!_free_i2c_bus())         // バスを開放させる。
        return  _set_i2c_error(I2C_BUS_NOT_FREE);  // バスが開放されない場合にはエラー・フラグをセットして戻る

    _I2C_STR();                   // スタート・コンディション発行

    if (!_put_i2c2(i2c_adr))      // I2C アドレス送信
        return  _set_i2c_error(I2C_ADDR_NACK); // 対象デバイスがノーリアクションならエラー・フラグをセットして戻る

    if (!_put_i2c2(reg_adr))      // レジスタアドレス送信
        return  _set_i2c_error(I2C_REG_ADDR_NACK); // サブ・アドレスでNACK発生ならエラー・フラグをセットして戻る


    do{
        if (!_put_i2c2(*data++))  // データ送信
            return  _set_i2c_error(I2C_DATA_NACK); // データ送信でNACK発生
    }while(--size);
    _I2C_STPR();                  // 正常終了でバスを開放
    return  _clear_i2c_error();   // エラー・フラグをクリアして戻る
}

• 最初にI2Cバスが開放状態であることを確認/バスを開放します。
• 開放できなければ、エラーで戻ります。
• スタート･コンディションを発行してバスの使用を開始します。
• EEPROMのアドレスを指定して送信方向でアドレスを送信します。
• 次にEEPROM内部の読み出したいアドレスを送信します。
• リスタートをかけます。
• EEPROMのアドレスを指定して受信方向でアドレスを送信します。
• 指定したアドレスからのデータの読み出しを行ないます。
• 読み出しの際に、最後のデータでなければ、ackeをセットしてACK応答するようにしてアセンブラの__get_i2cを呼び出して処理します。
• 最後のデータについてはackeをクリアしてNACK応答する設定で__get_i2cを呼び出して処理します。

u8 read_i2c_block(u8 i2c_adr, u8 reg_adr, u8 *data, u8 size)
{
    u8  d;
    i2c_adr &= 0xfe; 
    if (!_free_i2c_bus())
        return  _set_i2c_error(I2C_BUS_NOT_FREE);

    _I2C_STR();                     // スタート･コンディション発行

    if (!_put_i2c2(i2c_adr))        // I2C アドレス送信
        return  _set_i2c_error(I2C_ADDR_NACK); // 対象デバイスがノーリアクションなら、エラー・フラグを設定して戻る

    if (!_put_i2c2(reg_adr))        // レジスタアドレス送信
        return  _set_i2c_error(I2C_REG_ADDR_NACK); // サブ・アドレスでNACKならエラー・フラグを設定して戻る

    _I2C_STR();                     // リスタート

    if (!_put_i2c2(i2c_adr | 0x01)) // I2C アドレス(READ)送信
        return  _set_i2c_error(I2C_RADDR_NACK);  // 対象デバイスがノーリアクションならエラー・フラグを設定して戻る

    _ACK_EN();              // ACK 許可
    do{
        if (size == 1)      // 最後のバイト?
            _ACK_DS();      // マスタ受信最後のバイトならNACKに設定
        d = _get_i2c();     // データの読み込み
        *data++ = d;        // 読み込みデータをバッファにセット
    }while(--size);

    _I2C_STPR();            // バスを開放

    return  _clear_i2c_error(); // エラー・フラグをクリアして戻る
}

u8      eep_read_buf[32];   // read buffer
u8      eep_write_buf[16];  // write buffer
u8      result;             // for result flag

#define     ADR_EEP     0xa0    // slave address
//              1010xxxyB
//              ||||||||
//              |||||||+--  R/W#
//              |||||++---  P1/P0 (fixed 00)
//              ||||+-----  A2 (fixed 0)
//              ++++------  I2C Addr (fix)

• アセンブラ記述の関数を使用して、バッファ中の16バイトのデータをEEPROMの00〜0F番地に書き込みます。
  result = _write_i2c_block(ADR_EEP, 0x00, eep_write_buf, 16);
• アセンブラ記述の関数を使用して、EEPROMの00〜1F番地のデータをバッファに読み出します。
  result = _read_i2c_block(ADR_EEP, 0x00, eep_read_buf, 32);
• C言語記述の関数を使用して、バッファ中の16バイトのデータをEEPROMの00〜0F番地に書き込みます。
  result = write_i2c_block(ADR_EEP, 0x00, eep_write_buf, 16);
• C言語記述の関数を使用して、EEPROMの00〜1F番地のデータをバッファに読み出します。
  result = read_i2c_block(ADR_EEP, 0x00, eep_read_buf, 32);

(2006/03)

(2008/04)